Amazon Data Lifecycle Managerによるバックアップ自動化を試す

# EC2インスタンスの作成
resource "aws_instance" "example" {
  ami                         = var.ami_id
  instance_type               = "t3.micro"
  subnet_id                   = var.subnet_id
  associate_public_ip_address = false

  # EC2にもタグ付与
  tags = {
    Backup = "true"
  }

  # ルートボリュームの設定
  root_block_device {
    volume_size = 10
    volume_type = "gp3"

    tags = {
      Backup = "true"
    }    
  }
}

# IAMロールの作成（DLM用）
resource "aws_iam_role" "dlm_role" {
  name = "DLMServiceRole"

  assume_role_policy = jsonencode({
    Version = "2012-10-17"
    Statement = [
      {
        Effect = "Allow"
        Principal = {
          Service = "dlm.amazonaws.com"
        }
        Action = "sts:AssumeRole"
      }
    ]
  })
}

# IAMポリシーのアタッチ（DLMに必要な権限）
data "aws_caller_identity" "current" {}

data "aws_region" "current" {}

resource "aws_iam_role_policy" "dlm_policy" {
  name = "DLMPolicy"
  role = aws_iam_role.dlm_role.id

  policy = jsonencode({
    Version = "2012-10-17"
    Statement = [
      {
        Effect = "Allow"
        Action = [
          "ec2:CreateSnapshot",
          "ec2:DeleteSnapshot",
          "ec2:DescribeVolumes",
          "ec2:DescribeSnapshots",
          "ec2:CreateTags"
        ]
        Resource = "*"
      }
    ]
  })
}


# DLMライフサイクルポリシーの作成
resource "aws_dlm_lifecycle_policy" "ebs_snapshot_policy" {
  description = "Policy to take EBS snapshot every hour"

  execution_role_arn = aws_iam_role.dlm_role.arn

  state = "ENABLED"

  policy_details {
    resource_types = ["VOLUME"]

    target_tags = {
      Backup = "true"
    }

    schedule {
      name = "HourlySnapshots"

      create_rule {
        interval      = 1
        interval_unit = "HOURS"
        times = [ "19:45" ]
      }

      retain_rule {
        count = 12 # 12時間分のスナップショットを保持
      }
    }
  }
}

# 追加のEBSボリューム
resource "aws_volume_attachment" "ebs_attach" {
  device_name = "/dev/sdh"
  volume_id   = aws_ebs_volume.additional_volume.id
  instance_id = aws_instance.example.id
}

# EBSボリュームにタグを付与（DLMポリシー対象にするため）
resource "aws_ebs_volume" "additional_volume" {
  availability_zone = aws_instance.example.availability_zone
  size              = 8
  type              = "gp3"

  tags = {
    Backup = "true"
  }
}